$noop(When viewing this in a web browser press CTRL+S to save the file with the correct encoding)


$noop(Remove Unicode lookalikes)

$setmulti(_unicode_src,０; １; ２; ３; ４; ５; ６; ７; ８; ９;  ; ‘; ’; ‚; ‛; “; ”; „; ‟; ‐; ‑; –; —; ‒; ―; ․; ‥; …; ‼; ⁇; ⁄; ∕; ／; 〜; ～; （; ［; ＜; ）; ］; ＞; ？; ！; ：; ；; ，; 　; ＂; ＃; ＄; ％; ＆; ＇; ＊; ＋; －; ．; ＝; ＠; ＼; ＾; ＿; ｛; ｜; ｝; −; ′; ″; Ａ; Ｂ; Ｃ; Ｄ; Ｅ; Ｆ; Ｇ; Ｈ; Ｉ; Ｊ; Ｋ; Ｌ; Ｍ; Ｎ; Ｏ; Ｐ; Ｑ; Ｒ; Ｓ; Ｔ; Ｕ; Ｖ; Ｗ; Ｘ; Ｙ; Ｚ; ａ; ｂ; ｃ; ｄ; ｅ; ｆ; ｇ; ｈ; ｉ; ｊ; ｋ; ｌ; ｍ; ｎ; ｏ; ｐ; ｑ; ｒ; ｓ; ｔ; ｕ; ｖ; ｗ; ｘ; ｙ; ｚ; ⁃; ⸺; ⸻; ﹘; ﹣; ʼ; ʹ; ´; `)
$setmulti(_unicode_dst,0; 1; 2; 3; 4; 5; 6; 7; 8; 9;  ; '; '; \,; '; "; "; "; "; -; -; -; -; -; -; .; ..; ...; !!; ??; /; /;  / ; ~; ~;  \(;  [; <; \) ; ] ; >; ? ; ! ; :; ;; \,;  ; "; #; \$; \%; &; '; *; +; -; .; =; @; \\; ^; _; {; |; }; -; '; "; A; B; C; D; E; F; G; H; I; J; K; L; M; N; O; P; Q; R; S; T; U; V; W; X; Y; Z; a; b; c; d; e; f; g; h; i; j; k; l; m; n; o; p; q; r; s; t; u; v; w; x; y; z; -; -; -; -; -; '; '; '; ')

$foreach(artist; albumartist; title; album; composer; discsubtitle,
	$set(_tag,%_loop_value%)
	$foreach(%_unicode_src%,
		$set(_search,%_loop_value%)
		$set(_replace,$getmulti(%_unicode_dst%,$add(%_loop_count%,-1)))
		$set(%_tag%,$replace($get(%_tag%),%_search%,%_replace%))
		$set(%_tag%,$trim($rreplace($get(%_tag%), +, )))
	)
)

$noop(Consistent spacing for CV credits)

$foreach(artist; albumartist,
	$set(%_loop_value%,$rreplace($get(%_loop_value%),\(?i\) *\\\( *CV[.:：]? *, \(CV: ))
)

$noop(Format MusicBrainz enums for display)

$setmulti(releasetype,$title($replace(%releasetype%,ep,EP)))

$noop(Remove unwanted MusicBrainz tags)

$delete(musicbrainz_originalartistid)
$delete(musicbrainz_originalalbumid)
$delete(musicbrainz_workid)

$noop(Prefer BARCODE tag over UPC tag)

$set(barcode,$if2(%barcode%,%upc%))
$delete(upc)

$noop(Ignore [none] barcode)

$replacemulti(%barcode%,[none],)

$noop(Ignore [none] catalog number)

$replacemulti(%catalognumber%,[none],)

$noop(Ignore catalog number for Digital Media)

$if($eq_any(%media%,Digital Media),
	$delete(catalognumber)
)

$noop(Ignore soundtrack type on non-album releases)

$if($in(%releasetype%,Album),,
	$replacemulti(%releasetype%,Soundtrack,)
)

$noop(Keep only wanted tags)

$keep(
	artist,
	album,
	albumartist,
	title,
	barcode,
	catalognumber,
	tracknumber,
	discnumber,
	isrc,
	composer,
	tracktotal,
	totaltracks,
	disctotal,
	totaldiscs,
	media,
	date,
	releasetype,
	url,
	source,
	encoder,
	replaygain_album_gain,
	replaygain_album_peak,
	replaygain_track_gain,
	replaygain_track_peak,
	musicbrainz_artistid,
	musicbrainz_albumid,
	musicbrainz_albumartistid,
	musicbrainz_releasegroupid,
	musicbrainz_recordingid,
	musicbrainz_trackid
)